Beverly Smith wrote:
> how does one make color postscript files in IDL?
> I'm using:
>> set_plot,'ps'
>> device,/color,bits=8,/landscape,filename='test.ps'
>> plot,x,y,color=12
>> device,/close
> how do i get the standard colors like blue,red,green
> in a postscript file?
The following procedure may be useful.
;----------------------------------------------------------- ---------------
pro colors, start = start
;+
; Purpose:
; Load the sixteen McIDAS graphics colors into the current color
table.
;
; Calling Sequence:
; COLORS, START = START
;
; Optional Keywords:
; START Start index in the color table where the McIDAS graphics
; colors will be loaded (default = 0).
;
; Notes:
; The color table assignments are as follows
; 0 => black
; 1 => magenta
; 2 => cyan
; 3 => yellow
; 4 => green
; 5 => red
; 6 => blue
; 7 => white
; 8 => navy
; 9 => gold
; 10 => pink
; 11 => aquamarine
; 12 => orchid
; 13 => gray
; 14 => sky
; 15 => beige
;
; Example:
;
;; Display a greyscaled image using color table 0, reserving 16 colors
;; at the top of the color table. Then define the top 16 color table
;; entries, and write some colored text.
;
;window, /free, xs = 356, ys = 500
;hicolor = byte( !d.table_size - 1 - 16 )
;loadct, 0, ncolors = hicolor + 1
;tv, bytscl( dist( 256 ), top = hicolor - 1 )
;colors, start = hicolor
;magenta = hicolor + 1B
;red = hicolor + 5B
;green = hicolor + 4B
;blue = hicolor + 6B
;xyouts, 0, 300, 'Magenta', /device, color = magenta
;xyouts, 0, 350, 'Red', /device, color = red
;xyouts, 0, 400, 'Green', /device, color = green
;xyouts, 0, 450, 'Blue', /device, color = blue
;xloadct, ncolors = hicolor + 1
;
; Revised:
; 24-JULY-1996 Liam Gumley, CIMSS/SSEC
;-
;- check keywords
if n_elements( start ) eq 0 then start = 0
;- load McIDAS graphics color tables
r = [0,255,0,255,0,255,0,255,0,255,255,112,219,127,0,255]
g = [0,0,255,255,255,0,0,255,0,187,127,219,112,127,163,171]
b = [0,255,255,0,0,0,255,255,115,0,127,147,219,127,255,127]
tvlct, r, g, b, start
end
;----------------------------------------------------------- ---------------
|
comp.lang.idl-pvwave archive
Members
Search
Help
Login
Home
