comp.lang.idl-pvwave archive: archive » Re: Ordered index array

Home » Public Forums » archive » Re: Ordered index array

Show: Today's Messages :: Show Polls :: Message Navigator
E-mail to friend

Re: Ordered index array [message #45428 is a reply to message #45424]

Thu, 08 September 2005 05:30

Paolo Grigis
Messages: 171
Registered: December 2003

Senior Member

Emmanuel Christophe wrote:
> Thanks Paolo,
> Your function does exactly what I want, but my problem is precisely that
> I need to do it on huge array (300 000 elements at least), that why i'm
> looking for a more 'IDL' way to do it :)
>
> Emmanuel
Ok, let's do it. We'll use a loop, but this should not be too
bad as long as you don't have more than a few million elements,
provided that we just do simple operations in the loop.

PRO test2

a=[1,3,3,1,2,3,2,2,1,2,3]

c=lonarr(n_elements(a))

h=histogram(a,min=1L,reverse_ind=ri)

listlowestind=replicate(-1L,n_elements(h))

FOR i=0L,n_elements(h)-1 DO BEGIN
IF ri[i] NE ri[i+1] THEN listlowestind[i]=ri[ri[i]]
ENDFOR

indok=where(listlowestind GT -1L,countindok)
indoffset=n_elements(listlowestind)-countindok
indsorted=(sort(listlowestind))

FOR i=0L,countindok-1 DO BEGIN
this_element=a[listlowestind[indsorted[i+indoffset]]]
c[ri[ri[this_element-1]:ri[this_element]-1]]=i+1
ENDFOR

print,c

end

The idea here is to use histogram to scout for the first occurrence
of each integer number and store it in listlowestind. We then
sort the list, such that we know which element occurs first,
and then with a second loop we fill the output array c with
the occurrences of each element, and since we have sorted the
array first, we know which rank to assign to each element.
This should be moderately efficient. I assumed that the array
a has integer elements starting from 1, if not the case, just
sum 1-min(a) to the array before performing the operation.

Ciao,
Paolo

>
>
>
>
>> But this will fail if 'a' has more elements than the number of
>> its different values, for instance a=[3,3,1,2,3,2,2,1,2,3].
>>
>> One could try this:
>>
>> PRO test
>>
>> a=[3,3,1,2,3,2,2,1,2,3]
>>
>> b=a
>> c=intarr(n_elements(a))
>>
>> h=histogram(a,min=1,reverse_ind=ri)
>>
>> done=0
>> rank=1
>> WHILE NOT done DO BEGIN
>> actual_value=b[0]
>> ind_actual_value=ri[ri[actual_value-1]:ri[actual_value]-1]
>> c[ind_actual_value]=rank
>> rank=rank+1
>> indremove=where(b NE actual_value,count)
>> IF count GT 0 THEN b=b[indremove] ELSE done=1
>> ENDWHILE
>>
>> print,a
>> print,c
>>
>> END
>>
>>
>> but it will get inefficient as the numbers of different values
>> in 'a' grows, as the code in the loop get called more and more
>> times...
>>
>> Ciao,
>> Paolo
>>
>>
>>> Cheers,
>>>
>>> David
>>>
>>>

Report message to a moderator

[Message index]

		Re: Ordered index array By: Emmanuel Christophe on Thu, 08 September 2005 07:51
		Re: Ordered index array By: David Fanning on Thu, 08 September 2005 06:55
		Re: Ordered index array By: Paolo Grigis on Thu, 08 September 2005 06:51
		Re: Ordered index array By: David Fanning on Thu, 08 September 2005 06:08
		Re: Ordered index array By: David Fanning on Thu, 08 September 2005 06:02
		Re: Ordered index array By: Paolo Grigis on Thu, 08 September 2005 05:30
		Re: Ordered index array By: Paolo Grigis on Thu, 08 September 2005 03:03
		Re: Ordered index array By: Emmanuel Christophe on Thu, 08 September 2005 01:58
		Re: Ordered index array By: Emmanuel Christophe on Thu, 08 September 2005 01:48
		Re: Ordered index array By: Paolo Grigis on Thu, 08 September 2005 01:22
		Re: Ordered index array By: David Fanning on Wed, 07 September 2005 10:17
		Re: Ordered index array By: David Fanning on Wed, 07 September 2005 10:01

Previous Topic:	2 arrays, average, missing data
Next Topic:	Re: 2 arrays, average, missing data

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Fri Oct 10 10:02:21 PDT 2025

Total time taken to generate the page: 1.03916 seconds