comp.lang.idl-pvwave archive: archive

Home » Public Forums » archive » Re: fast search

Show: Today's Messages :: Show Polls :: Message Navigator
E-mail to friend

Re: fast search [message #50803 is a reply to message #50798]

Tue, 17 October 2006 10:17

greg michael
Messages: 163
Registered: January 2006

Senior Member

Actually, there's a mistake in that code - it's got mixed
procedure/function syntax. Should be like this:

function ss_MakeGalaxies,n
p=replicate({x:0.,y:0.,z:0.},n)
seed=0
p.x=randomu(seed,n)*1000.
p.y=randomu(seed,n)*1000.
p.z=randomu(seed,n)*1000.
return,p
end

function ss_distance,p1,p2
return,sqrt((p2.x-p1.x)^2+(p2.y-p1.y)^2+(p2.z-p1.z)^2)
end

pro splitsearch,p,dist
;recursively splits the search volume into n_split^3 subvolumes. When
;there are fewer than 'threshold' points
;in a subvolume, checks for matches the brute force way - every point
;against every other.

n_split=3
threshold=75

s=(size(p))[1]

if s gt threshold then begin
xmn=min(p.x,max=xmx)
ymn=min(p.y,max=ymx)
zmn=min(p.z,max=zmx)

xg=xmn+findgen(n_split+1)*(xmx-xmn)/n_split ;grid boundaries
yg=ymn+findgen(n_split+1)*(ymx-ymn)/n_split
zg=zmn+findgen(n_split+1)*(zmx-zmn)/n_split

for j=0,n_split-1 do begin
for k=0,n_split-1 do begin
for l=0,n_split-1 do begin
w= where( (p.x ge xg[j]-dist) and (p.x lt xg[j+1]+dist) and $
(p.y ge yg[k]-dist) and (p.y lt yg[k+1]+dist) and $
(p.z ge zg[l]-dist) and (p.z lt zg[l+1]+dist))
if n_elements(w) ge 2 then begin
splitsearch,p[w],dist
endif
endfor
endfor
endfor

endif else begin
for i=0,s-2 do begin
for j=i+1,s-1 do begin
if ss_distance(p[i],p[j]) le dist then begin
print,p[i],p[j]
endif
endfor
endfor
endelse
end

Then call it using:

IDL> p=ss_MakeGalaxies(1e5)
IDL> splitsearch,p,.5
{ 454.665 175.794 87.0097}{ 454.816 175.504
87.3471}
{ 556.761 981.076 933.809}{ 556.654 980.922
934.065}
{ 981.340 196.286 105.551}{ 981.387 196.102
105.703}

The left and right columns are the neigbouring (< .5 units distant) xyz
triples.

regards,
Greg

Report message to a moderator

[Message index]

		Re: fast search By: greg michael on Wed, 18 October 2006 08:25
		Re: fast search By: greg michael on Tue, 17 October 2006 11:25
		Re: fast search By: greg michael on Tue, 17 October 2006 10:17
		Re: fast search By: greg michael on Tue, 17 October 2006 07:15
		Re: fast search By: Paolo Grigis on Tue, 17 October 2006 05:53
		Re: fast search By: m.goullant@gmail.com on Thu, 19 October 2006 04:01
		Re: fast search By: m.goullant@gmail.com on Thu, 19 October 2006 03:46

Previous Topic:	Re: vector of bin indices using histogram?
Next Topic:	Re: Weirdest Error Ever

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Fri Oct 10 20:55:54 PDT 2025

Total time taken to generate the page: 0.55866 seconds