comp.lang.idl-pvwave archive: archive » Re: Testers needed for TV benchmark

Home » Public Forums » archive » Re: Testers needed for TV benchmark

Show: Today's Messages :: Show Polls :: Message Navigator
E-mail to friend

Re: Testers needed for TV benchmark [message #26131 is a reply to message #26129]

Wed, 08 August 2001 14:47

Liam E. Gumley
Messages: 378
Registered: January 2000

Senior Member

The true color version of my test procedure gives slightly lower display
and animation rates, at least on my system:

PRO TEST_TRUE, DELAY=DELAY

;- Load the image
filename = filepath('rose.jpg', subdir='examples/data')
read_jpeg, filename, image
xsize = 3 * 227
ysize = 3 * 149
image = rebin(image, 3, xsize, ysize)

;- Set initial parameters
nframes = 20
if (n_elements(delay) eq 0) then delay = 0.05

;- Display image in pixmap windows
t0 = systime(1)
for frame = 0, nframes - 1 do begin
window, frame, /pixmap, xsize=xsize, ysize=ysize
tv, shift(image, 0, 10 * frame, 0), true=1
endfor
t1 = systime(1)
print, 'Display rate (frames/sec) = ', $
float(nframes) / (t1 - t0)

;- Animate the images
window, /free, xsize=xsize, ysize=ysize
t0 = systime(1)
for frame = 0, nframes - 1 do begin
device, copy=[0, 0, xsize, ysize, 0, 0, frame]
wait, delay
endfor
t1 = systime(1)
print, 'Animation rate (frames/sec) = ', $
float(nframes) / (t1 - t0)

END

IDL> test_true
Display rate (frames/sec) = 3.3394557
Animation rate (frames/sec) = 15.491868
IDL> test_true, delay=0.0
Display rate (frames/sec) = 3.3344448
Animation rate (frames/sec) = 45.351475

Cheers,
Liam.
Practical IDL Programming
http://www.gumley.com/

Report message to a moderator

[Message index]

		Re: Testers needed for TV benchmark By: Pavel A. Romashkin on Wed, 08 August 2001 14:58
		Re: Testers needed for TV benchmark By: Liam E. Gumley on Wed, 08 August 2001 14:47
		Re: Testers needed for TV benchmark By: Liam E. Gumley on Wed, 08 August 2001 14:33
		Re: Testers needed for TV benchmark By: Pavel A. Romashkin on Wed, 08 August 2001 14:23
		Re: Testers needed for TV benchmark By: John-David T. Smith on Wed, 08 August 2001 14:12
		Re: Testers needed for TV benchmark By: Pavel A. Romashkin on Wed, 08 August 2001 14:09
		Re: Testers needed for TV benchmark By: billb on Wed, 08 August 2001 13:55
		Re: Testers needed for TV benchmark By: Liam E. Gumley on Wed, 08 August 2001 11:24
		Re: Testers needed for TV benchmark By: billb on Thu, 09 August 2001 07:46
		Re: Testers needed for TV benchmark By: R.Bauer on Sun, 19 August 2001 11:20
		Re: Testers needed for TV benchmark By: karl_schultz on Thu, 09 August 2001 08:42

Previous Topic:	Re: FFT's and images: or My 4th day on what I thought would take me only 6hrs
Next Topic:	openr keyword conflict

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Wed Oct 08 18:58:47 PDT 2025

Total time taken to generate the page: 0.00467 seconds