comp.lang.idl-pvwave archive: archive » Re: Removing some but not all spaces in a string

Home » Public Forums » archive » Re: Removing some but not all spaces in a string

Show: Today's Messages :: Show Polls :: Message Navigator
E-mail to friend

Re: Removing some but not all spaces in a string [message #61764 is a reply to message #61758]

Mon, 28 July 2008 19:41

Craig Markwardt
Messages: 1869
Registered: November 1996

Senior Member

wlandsman <wlandsman@gmail.com> writes:

> I'm looking for suggestions for the best way remove the spaces around
> "operators" (e.g. <. > , =) in a string but not around other
> characters. For example, I want the string
>
> 'name = ngc 5548, v <15'
>
> to become
>
> 'name=ngc 5548, v<15'

I usually do specialized string twizzling at the byte level, which is
done in TEST2 below. I'm not sure if TEST2 faster or more elegant
than your TEST, but it avoids all the gluing and ungluing inherent in
the STREGEX() method. It's a pity there isn't a STREPLACE() which
handles regular expressions.

I also attached a version based on REPSTR() but since that sub-routine
itself does glue/unglue, it's just hiding the mess behind a facade.

Craig

pro test2, st
space = 32b
ops = '<>=' ;; Operations to delete spaces
bops = byte(ops)

st = strtrim(strcompress(st),2)
if st EQ '' then return

bb = byte(st)
mask = 0b
for i = 0, n_elements(bops)-1 do begin
mask = mask OR [(bb EQ space AND bb(1:*) EQ bops(i)),0b]
mask = mask OR [0b,(bb EQ bops(i) AND bb(1:*) EQ space)]
endfor

wh = where(mask EQ 0)
st = string(byte(bb(wh)))
return
end

pro test3, st
space = ' '
ops = ['<','>','='] ;; Operations to delete spaces

st = strtrim(strcompress(st),2)
if st EQ '' then return
for i = 0, n_elements(ops)-1 do begin
op = ops(i)
st = repstr(st, ' '+op, op)
st = repstr(st, op+' ', op)
endfor
return
end

--
------------------------------------------------------------ --------------
Craig B. Markwardt, Ph.D. EMAIL: craigmnet@REMOVEcow.physics.wisc.edu
Astrophysics, IDL, Finance, Derivatives | Remove "net" for better response
------------------------------------------------------------ --------------

Report message to a moderator

[Message index]

		Re: Removing some but not all spaces in a string By: humanumbrella on Tue, 29 July 2008 09:09
		Re: Removing some but not all spaces in a string By: Craig Markwardt on Tue, 29 July 2008 08:43
		Re: Removing some but not all spaces in a string By: wlandsman on Tue, 29 July 2008 08:40
		Re: Removing some but not all spaces in a string By: Craig Markwardt on Tue, 29 July 2008 08:37
		Re: Removing some but not all spaces in a string By: humanumbrella on Tue, 29 July 2008 08:33
		Re: Removing some but not all spaces in a string By: David Fanning on Tue, 29 July 2008 08:27
		Re: Removing some but not all spaces in a string By: Bob[3] on Tue, 29 July 2008 08:16
		Re: Removing some but not all spaces in a string By: humanumbrella on Tue, 29 July 2008 05:45
		Re: Removing some but not all spaces in a string By: Jeremy Bailin on Tue, 29 July 2008 04:26
		Re: Removing some but not all spaces in a string By: Craig Markwardt on Mon, 28 July 2008 19:41

Previous Topic:	Array has a corrupted discriptor, reliable?
Next Topic:	error on stddev estimate

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Fri Oct 10 11:23:27 PDT 2025

Total time taken to generate the page: 0.96192 seconds