comp.lang.idl-pvwave archive: archive » Re: The IDL way: Find last non-zero value

Home » Public Forums » archive » Re: The IDL way: Find last non-zero value

Show: Today's Messages :: Show Polls :: Message Navigator
E-mail to friend

Re: The IDL way: Find last non-zero value [message #67745 is a reply to message #67744]

Sun, 23 August 2009 19:10

penteado
Messages: 866
Registered: February 2018

Senior Member
Administrator

On Aug 23, 9:32 pm, Chris <beaum...@ifa.hawaii.edu> wrote:
> sz = size(array)
> ncol = sz[1]
> nrow = sz[2]
> nonzero = where(array ne 0)
> ind = array_indices(array, nonzero)
> sorted = sort(ind[0, *])
> result = fltarr(nrow) - 1
> result[ind[1, sorted]] = ind[0, sorted]

That gave me this idea:

function lastnz2d,array
;Returns a vector with the index of the last nonzero element
;of each line of array (-1 if that line only has zeroes)
sz=size(array)
;Find all nonzero elements in array
nonzero=where(array ne 0,count)
;Get out if all elements of array are zero
if (count eq 0) then return,replicate(-1,sz[2])
;Find the row/column number of each nonzero element
ind=array_indices(array,nonzero)
;Initialize the result vector
res=lonarr(sz[2])-1L
;The repeated numbers in the second column of ind are
;the elements in the same line, so find the last occurrence
;of each sequence of repeated numbers
uni=uniq(ind[1,*])
;The result of uniq is the row number in ind of the last nonzero
element
;of each row in array
res[ind[1,uni]]=ind[0,uni]
return,res
end

It is the same up to the use array_indices to get row and column
numbers into ind. For each row of array with nonzero elements, the
corresponding rows of ind will have the same number in the second
column (since it is the row number in array), with the increasing
column numbers in the first column. So I use uniq on the second column
of ind to retrieve every row in ind that corresponds to a last nonzero
element in a row of array.

Report message to a moderator

[Message index]

		Re: The IDL way: Find last non-zero value By: Jeremy Bailin on Mon, 24 August 2009 19:53
		Re: The IDL way: Find last non-zero value By: Jeremy Bailin on Mon, 24 August 2009 19:43
		Re: The IDL way: Find last non-zero value By: penteado on Mon, 24 August 2009 18:35
		Re: The IDL way: Find last non-zero value By: Jeremy Bailin on Mon, 24 August 2009 17:12
		Re: The IDL way: Find last non-zero value By: Eric Hudson on Mon, 24 August 2009 13:42
		Re: The IDL way: Find last non-zero value By: cgguido on Sun, 23 August 2009 20:39
		Re: The IDL way: Find last non-zero value By: penteado on Sun, 23 August 2009 19:10
		Re: The IDL way: Find last non-zero value By: Chris[6] on Sun, 23 August 2009 17:32

Previous Topic:	Re: Histogram Too Many Array Elements
Next Topic:	Integer - decimal help

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Fri Oct 10 09:00:01 PDT 2025

Total time taken to generate the page: 3.60025 seconds