comp.lang.idl-pvwave archive: archive » Re: How 2 show animations.

Home » Public Forums » archive » Re: How 2 show animations.

Show: Today's Messages :: Show Polls :: Message Navigator
E-mail to friend

Re: How 2 show animations. [message #79488 is a reply to message #79484]

Fri, 02 March 2012 06:15

David Fanning
Messages: 11724
Registered: August 2001

Senior Member

DavePoreh writes:

> I have 52 images (in .png) format and i would like to make it like
> animation in IDL. can anyone help me.

If you have IDL 8, the IDLffVideoWrite object produces
animations in mpg4 and avi format that don't look so
bad. You can specify which Codec you want to use to
build the animation, and so on. Quite a few features.

Here is a very simple example that makes an AVI movie of all
the PNG files in the current directory. Presumably, you
have named them in a sensible way. :-)

;--------------------------------------------------------
PRO Movie_Example

Compile_Opt idl2

; Open the video recorder.
video_file = 'movie_example.avi'
video = IDLffVideoWrite(video_file, Format='avi')

; Configure the video output for the PNG files you
; plan to add.
framerate = 5
xsize = 750
ysize = 600
stream = video.AddVideoStream(xsize, ysize, framerate)

; Get the files.
files = File_Search('*.png', COUNT=fileCnt)
FOR j=0,fileCnt-1 DO BEGIN

; Read the PNG file.
image = Read_PNG(files[j])

; Save the image in the video stream
void = video.Put(stream, image)

ENDFOR

; Clean things up.
video.Cleanup

END
;--------------------------------------------------------

Cheers,

David

--
David Fanning, Ph.D.
Fanning Software Consulting, Inc.
Coyote's Guide to IDL Programming: http://www.idlcoyote.com/
Sepore ma de ni thui. ("Perhaps thou speakest truth.")

Report message to a moderator

[Message index]

		Re: How 2 show animations. By: d.poreh on Mon, 05 March 2012 00:24
		Re: How 2 show animations. By: d.poreh on Sat, 03 March 2012 00:59
		Re: How 2 show animations. By: Brian Wolven on Fri, 02 March 2012 12:41
		Re: How 2 show animations. By: Michael Galloy on Fri, 02 March 2012 11:24
		Re: How 2 show animations. By: David Fanning on Fri, 02 March 2012 11:17
		Re: How 2 show animations. By: Christian on Fri, 02 March 2012 10:59
		Re: How 2 show animations. By: Brian Daniel on Fri, 02 March 2012 09:24
		Re: How 2 show animations. By: David Fanning on Fri, 02 March 2012 06:15

Previous Topic:	Getting Help in On-Line Communities
Next Topic:	saving a RAW data

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Fri Oct 10 14:14:51 PDT 2025

Total time taken to generate the page: 1.43869 seconds