comp.lang.idl-pvwave archive: archive

Home » Public Forums » archive » Sorting a matrix

Show: Today's Messages :: Show Polls :: Message Navigator
E-mail to friend

Re: Sorting a matrix [message #83422 is a reply to message #83346]

Fri, 01 March 2013 08:28

Jeremy Bailin
Messages: 618
Registered: April 2008

Senior Member

On 3/1/13 7:45 AM, Mats Lï¿½fdahl wrote:
> I'd like to sort a matrix M in such a way that the order of the rows is determined by the value in the first column. When the first column values are the same, the second column should be used, etc.
>
> Something like Craig Marqwardt's multisort (http://cow.physics.wisc.edu/~craigm/idl/down/multisort.pro), with M[0,*] used as key1, M[1,*] as key2, etc. But without actually having to specify the keys one by one. (Never mind which index counts as the column index :o)
>
> As the matrices I have in mind right now are integer arrays and do not have that many possible values (just -1,0,1), I thought about turning the matrix into a 1D string array with the length of each string equal to the number of columns and translating the column values into characters in the string, like A for -1, B for 0, C for 1, and then sorting the string array. But I'd prefer a more general program, in case there is one out there.
>
> Pointers, ideas?
>

I've done something like this before by generating a single unique
index... something like this:

matrix = [[4,5,6], [4,6,8], [2,3,4], [4,6,7]]

matrixshape = size(matrix, /dimen)
; this gives you the range of each column:
matrixord = lonarr(matrixshape)
for i=0l,matrixshape[0]-1 do matrixord[i,*] = ord(matrix[i,*])
ordmax = max(matrixord, dimen=2)

; what do you need to multiply by to get a unique range?
column_multiply = [reverse(product(reverse(ordmax[1:*]+1), /int,
/cumul)), 1]

; create a unique key and sort on it
sortkey = total(matrixord * rebin(column_multiply,matrixshape, /sample),
/int, 1)
newmatrix = matrix[*, sort(sortkey)]

IDL> print, newmatrix
2 3 4
4 5 6
4 6 7
4 6 8

You'll need ORD(), which is part of JBIU which is currently inaccessible
because I'm in the process of moving domains. But here's a stub:

function ord, values

nvalues=n_elements(values)
sortvalues = sort(values)
uniqvalues = uniq(values[sortvalues])

nuniq = n_elements(uniqvalues)
ordlist = lindgen(nuniq)

; this is basically the histogram(total(/cumulative)) trick
h = histogram(uniqvalues,bin=1,min=0,reverse=ri)
outp = lonarr(size(values, /dimen))
outp[sortvalues] = ordlist[ri[0:nvalues-1]-ri[0]]

return, outp

end

Report message to a moderator

[Message index]

		Sorting a matrix By: Mats Löfdahl on Fri, 01 March 2013 04:45
		Re: Sorting a matrix By: Mats Löfdahl on Fri, 01 March 2013 08:49
		Re: Sorting a matrix By: Jeremy Bailin on Tue, 05 March 2013 21:22
		Re: Sorting a matrix By: Jeremy Bailin on Fri, 01 March 2013 08:28
		Re: Sorting a matrix By: Mats Löfdahl on Thu, 07 March 2013 05:32
		Re: Sorting a matrix By: Jeremy Bailin on Thu, 07 March 2013 16:34
		Re: Sorting a matrix By: Mats Löfdahl on Fri, 08 March 2013 16:14
		Re: Sorting a matrix By: cgguido on Fri, 08 March 2013 16:24
		Re: Sorting a matrix By: cgguido on Fri, 08 March 2013 14:24
		Re: Sorting a matrix By: Jeremy Bailin on Fri, 08 March 2013 15:51
		Re: Sorting a matrix By: Mats Löfdahl on Fri, 08 March 2013 16:31

Previous Topic:	where, or, and loops. There has to be a better way.
Next Topic:	SPAWN with AWK

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Sun Oct 12 12:12:41 PDT 2025

Total time taken to generate the page: 0.64196 seconds