comp.lang.idl-pvwave archive: archive » Re: List of Points --> ROI via IDLVECTOR data type for iimage itool

Home » Public Forums » archive » Re: List of Points --> ROI via IDLVECTOR data type for iimage itool

Show: Today's Messages :: Show Polls :: Message Navigator
E-mail to friend

Re: List of Points --> ROI via IDLVECTOR data type for iimage itool [message #45807]

Fri, 14 October 2005 10:40

David Alexander
Messages: 26
Registered: August 2005

Junior Member

Edward,

OK, I see what you're trying to do.

There's no point visualization that I know of in iTools. However, you
could create a second image containing only the points, and overlay it
on top of the original. This is based on the same idea as my last
example. I'm setting the points to red in the overlay image, and making
all other pixels transparent.

pro test
x = bytscl(randomu(s,1000))
y = bytscl(randomu(s,1000))

newImage=bytarr(256,256)
newImage[x,y]=255

newImage=[[[newImage]],[[bytarr(256,256)]],[[bytarr(256,256) ]],[[newImage]]]

iimage,dist(256)
iimage,newImage,/OVERPLOT
end

If you don't want to mark individual pixels, but would rather put some
kind of symbol annotation in the location of each point, you could
overlay a 2D plot with symbols on the image, then turn off the plot
line. Something like this:

pro test
x = bytscl(randomu(s,100))
y = bytscl(randomu(s,100))

idx=SORT(x)
x=x[idx]
y=y[idx]

iimage,dist(256)
iplot,x,y,/OVERPLOT,LINESTYLE=6,SYM_INDEX=2

;Remove the axes
void=itGetCurrent(TOOL=oTool)
id=oTool->FindIdentifiers('*plot',/VISUALIZATIONS)
oPlot=oTool->GetByIdentifier(id)
oPlot->SetAxesStyleRequest,0

;Unselect the plot to force the axes to disappear
oPlot->Select,0
end

iPlot will always add axes, so the last few lines of my example show
how to turn those off. iplot also has many other keywords to set the
appearance (color, size, type, etc.) of the symbols.

Dave

Report message to a moderator

[Message index]

		Re: List of Points --> ROI via IDLVECTOR data type for iimage itool By: David Alexander on Fri, 14 October 2005 10:40
		Re: List of Points --> ROI via IDLVECTOR data type for iimage itool By: MarioIncandenza on Thu, 13 October 2005 15:08
		Re: List of Points --> ROI via IDLVECTOR data type for iimage itool By: David Alexander on Thu, 13 October 2005 13:15

Previous Topic:	Calling IDL from C
Next Topic:	Re: Deallocate Memory for a Structure

-=] Back to Top [=-

[ Syndicate this forum (XML) ] [

] [

]

Current Time: Fri Oct 10 18:16:24 PDT 2025

Total time taken to generate the page: 0.88017 seconds